10 REM *** GAME OF ACEY-DUCEY WRITTEN BY BILL PALMBY
  20 REM *** TRANSLATED TO RSTS/E BY DAVE AHL, DIGITAL
  30 REM *** EDUSYSTEM 50 REFACTORING BY RENAUD FIVET
  80 DIM D$(3)\ D$(0)="JACK"\ D$(1)="QUEEN"\ D$(2)="KING"\ D$(3)="ACE"
  90 DEF FNC(C)=INT(13*RND(1))+2
 100 RANDOMIZE
 101 PRINT "ACEY-DUCEY IS PLAYED IN THE FOLLOWING MANNER:"
 102 PRINT "THE DEALER (COMPUTER) DEALS TWO CARDS FACE UP."
 103 PRINT "YOU HAVE THE OPTION TO BET OR NOT TO BET DEPENDING"
 104 PRINT "ON WHETHER OR NOT YOU FEEL THE NEXT CARD WILL HAVE"
 105 PRINT "A VALUE BETWEEN THE FIRST TWO."
 106 PRINT "IF YOU DO NOT WANT TO BET, INPUT A 0."
 200 PRINT
 210 Q=100
 300 PRINT "YOU NOW HAVE"Q"DOLLARS."
 400 PRINT
 410 PRINT "HERE ARE YOUR NEXT TWO CARDS... "
 500 A=FNC(A)
 510 B=FNC(B)
 520 IF A>=B THEN 500
 550 C=A\ GOSUB 1000
 560 C=B\ GOSUB 1000
 600 PRINT
 610 PRINT "WHAT IS YOUR BET";\ INPUT M
 620 IF M>0 THEN 650
 630  PRINT "CHICKEN!!"
 640  GOTO 400
 650 IF M<=Q THEN 700
 660  PRINT "SORRY, MY FRIEND, BUT YOU BET TOO MUCH"
 670  PRINT "YOU HAVE ONLY"Q"DOLLARS TO BET."
 680  GOTO 600
 700 C=FNC(C)
 710 GOSUB 1000
 720 IF C<=A THEN 800
 730 IF C>=B THEN 800
 740  PRINT "YOU WIN!!!"
 750  Q=Q+M
 760  GOTO 300
 800 PRINT "SORRY, YOU LOSE."
 810 IF M>=Q THEN 900
 820  Q=Q-M
 830  GOTO 300
 900 PRINT
 910 PRINT "SORRY, FRIEND, BUT YOU BLEW YOUR WAD."
 920 PRINT "TRY AGAIN (YES OR NO)";\ INPUT A$
 930 IF A$="YES" THEN 200
 940 PRINT
 950 PRINT "O.K. HOPE YOU HAD FUN!!"
 960 STOP
1000 IF C>10 THEN 1030
1010  PRINT C\ RETURN
1030 PRINT D$(C-11)
1040 RETURN
1050 END