RABBIT: Refactoring BUNNY

 10 DIM R(5)
 20 FOR I=0 TO 5\ READ R(I)\ NEXT I
 30 DATA 82,65,66,66,73,84
 40 PRINT
 50 READ X\ IF X<0 THEN 40
 60 IF X>128 THEN 260
 70 PRINT TAB(10+X);\ READ Y\ Y=Y+X
 80 FOR I=X TO Y\ J=I-6*INT(I/6)
 90 PRINT CHR$(R(J));
100 NEXT I
110 GOTO 50
120 DATA 1,1,-1,0,2,45,5,-1,0,5,43,9,-1,0,7,41,11,-1
130 DATA 1,8,37,13,-1,2,9,36,14,-1,3,10,34,15,-1,4,10,32,16,-1
140 DATA 5,10,31,16,-1,6,10,30,15,-1,7,10,29,15,-1,8,11,28,15,-1
150 DATA 9,11,27,14,-1,10,11,26,14,-1,11,11,25,13,-1,12,10,24,12,-1
160 DATA 13,21,-1,14,19,-1,15,16,-1,17,12,-1,18,9,-1
170 DATA 19,7,-1,16,12,-1,13,17,-1,11,20,-1,10,22,-1
180 DATA 8,25,-1,7,27,-1,6,7,16,18,-1,5,7,16,19,-1
190 DATA 4,8,16,19,-1,3,9,15,20,-1,2,33,-1,1,34,-1
200 DATA 2,32,-1,3,31,-1,4,29,-1,6,27,-1,10,22,34,0,-1
210 DATA 14,3,19,6,28,3,35,0,-1,15,4,23,7,36,0,-1
220 DATA 14,4,21,0,24,6,37,0,-1,13,5,23,6,33,5,-1
230 DATA 12,17,31,2,-1,11,2,17,0,19,0,22,0,24,7,-1
240 DATA 10,1,17,1,22,0,24,0,29,0,-1
250 DATA 22,1,26,3,-1,27,2,-1,28,1,-1,4096
260 END
RUN


           AB
          RAB                                          BITRAB
          RABBIT                                     ABBITRABBI
          RABBITRA                                 TRABBITRABBI
           ABBITRABB                           ABBITRABBITRAB
            BBITRABBIT                        RABBITRABBITRAB
             BITRABBITRA                    ITRABBITRABBITRA
              ITRABBITRAB                 BBITRABBITRABBITR
               TRABBITRABB               ABBITRABBITRABBIT
                RABBITRABBI             RABBITRABBITRABB
                 ABBITRABBIT           TRABBITRABBITRAB
                  BBITRABBITRA        ITRABBITRABBITRA
                   BITRABBITRAB      BITRABBITRABBIT
                    ITRABBITRABB    BBITRABBITRABBI
                     TRABBITRABBI  ABBITRABBITRAB
                      RABBITRABBI RABBITRABBITR
                       ABBITRABBITRABBITRABBI
                        BBITRABBITRABBITRABB
                         BITRABBITRABBITRA
                           TRABBITRABBIT
                            RABBITRABB
                             ABBITRAB
                          ITRABBITRABBI
                       ABBITRABBITRABBITR
                     TRABBITRABBITRABBITRA
                    ITRABBITRABBITRABBITRAB
                  BBITRABBITRABBITRABBITRABB
                 ABBITRABBITRABBITRABBITRABBI
                RABBITRA  ITRABBITRABBITRABBI
               TRABBITR   ITRABBITRABBITRABBIT
              ITRABBITR   ITRABBITRABBITRABBIT
             BITRABBITR  BITRABBITRABBITRABBIT
            BBITRABBITRABBITRABBITRABBITRABBIT
           ABBITRABBITRABBITRABBITRABBITRABBIT
            BBITRABBITRABBITRABBITRABBITRABBI
             BITRABBITRABBITRABBITRABBITRABBI
              ITRABBITRABBITRABBITRABBITRABB
                RABBITRABBITRABBITRABBITRABB
                    ITRABBITRABBITRABBITRAB I
                        BBIT ABBITRA  ITRA   T
                         BITRA   TRABBITR     R
                        BBITR  B  RABBITR      A
                       ABBITR    TRABBIT   BITRAB
                      RABBITRABBITRABBIT ABB
                     TRA   T A  I RABBITRA
                    IT     TR   I R    T
                                IT  BBIT
                                     BIT
                                      IT


READY

TSS8 BCG BUNNY

Page 62 of DEC 101 BASIC Computer Games (3rd Print – March 1975)

Basic Computer Game Bunny source.

EduSystem 50 Port

  • DIM statement was missing in 110
  • Replaced : by \ as statement separator
 10 PRINT TAB(33); "BUNNY"
 20 PRINT TAB(15); "CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
 30 PRINT \ PRINT \ PRINT
100 REM  "BUNNY"  FROM AHL'S 'BASIC COMPUTER GAMES'
110 DIM B(4)
120 FOR I = 0 TO 4\ READ B(I)\ NEXT I
130 GOSUB 260
140 L = 64\ REM  ASCII LETTER CODE...
150 REM
160 PRINT
170 READ X\ IF X < 0 THEN 160
175 IF X > 128 THEN 240
180 PRINT TAB(10 + X); \ READ Y
190 FOR I = X TO Y\ J = I - 5 * INT(I / 5)
200 PRINT CHR$(L + B(J));
210 NEXT I
220 GOTO 170
230 REM
240 GOSUB 260\ GOTO 450
250 REM
260 FOR I = 1 TO 6\ PRINT CHR$(10); \ NEXT I
270 RETURN
280 REM
290 DATA 2,21,14,14,25
300 DATA 1,2,-1,0,2,45,50,-1,0,5,43,52,-1,0,7,41,52,-1
310 DATA 1,9,37,50,-1,2,11,36,50,-1,3,13,34,49,-1,4,14,32,48,-1
320 DATA 5,15,31,47,-1,6,16,30,45,-1,7,17,29,44,-1,8,19,28,43,-1
330 DATA 9,20,27,41,-1,10,21,26,40,-1,11,22,25,38,-1,12,22,24,36,-1
340 DATA 13,34,-1,14,33,-1,15,31,-1,17,29,-1,18,27,-1
350 DATA 19,26,-1,16,28,-1,13,30,-1,11,31,-1,10,32,-1
360 DATA 8,33,-1,7,34,-1,6,13,16,34,-1,5,12,16,35,-1
370 DATA 4,12,16,35,-1,3,12,15,35,-1,2,35,-1,1,35,-1
380 DATA 2,34,-1,3,34,-1,4,33,-1,6,33,-1,10,32,34,34,-1
390 DATA 14,17,19,25,28,31,35,35,-1,15,19,23,30,36,36,-1
400 DATA 14,18,21,21,24,30,37,37,-1,13,18,23,29,33,38,-1
410 DATA 12,29,31,33,-1,11,13,17,17,19,19,22,22,24,31,-1
420 DATA 10,11,17,18,22,22,24,24,29,29,-1
430 DATA 22,23,26,29,-1,27,29,-1,28,29,-1,4096
440 REM
450 END
RUN

                                 BUNNY
               CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY










           UN
          BUN                                          BUNNYB
          BUNNYB                                     NYBUNNYBUN
          BUNNYBUN                                 UNNYBUNNYBUN
           UNNYBUNNY                           NNYBUNNYBUNNYB
            NNYBUNNYBU                        UNNYBUNNYBUNNYB
             NYBUNNYBUNN                    YBUNNYBUNNYBUNNY
              YBUNNYBUNNY                 NNYBUNNYBUNNYBUNN
               BUNNYBUNNYB               UNNYBUNNYBUNNYBUN
                UNNYBUNNYBU             BUNNYBUNNYBUNNYB
                 NNYBUNNYBUN           YBUNNYBUNNYBUNNY
                  NYBUNNYBUNNY        NYBUNNYBUNNYBUNN
                   YBUNNYBUNNYB      NNYBUNNYBUNNYBU
                    BUNNYBUNNYBU    UNNYBUNNYBUNNYB
                     UNNYBUNNYBUN  BUNNYBUNNYBUNN
                      NNYBUNNYBUN YBUNNYBUNNYBU
                       NYBUNNYBUNNYBUNNYBUNNY
                        YBUNNYBUNNYBUNNYBUNN
                         BUNNYBUNNYBUNNYBU
                           NNYBUNNYBUNNY
                            NYBUNNYBUN
                             YBUNNYBU
                          UNNYBUNNYBUNN
                       NYBUNNYBUNNYBUNNYB
                     UNNYBUNNYBUNNYBUNNYBU
                    BUNNYBUNNYBUNNYBUNNYBUN
                  NYBUNNYBUNNYBUNNYBUNNYBUNN
                 NNYBUNNYBUNNYBUNNYBUNNYBUNNY
                UNNYBUNN  UNNYBUNNYBUNNYBUNNY
               BUNNYBUN   UNNYBUNNYBUNNYBUNNYB
              YBUNNYBUN   UNNYBUNNYBUNNYBUNNYB
             NYBUNNYBUN  BUNNYBUNNYBUNNYBUNNYB
            NNYBUNNYBUNNYBUNNYBUNNYBUNNYBUNNYB
           UNNYBUNNYBUNNYBUNNYBUNNYBUNNYBUNNYB
            NNYBUNNYBUNNYBUNNYBUNNYBUNNYBUNNY
             NYBUNNYBUNNYBUNNYBUNNYBUNNYBUNNY
              YBUNNYBUNNYBUNNYBUNNYBUNNYBUNN
                UNNYBUNNYBUNNYBUNNYBUNNYBUNN
                    BUNNYBUNNYBUNNYBUNNYBUN Y
                        YBUN YBUNNYB  NYBU   B
                         BUNNY   NYBUNNYB     U
                        YBUNN  U  YBUNNYB      N
                       NYBUNN    NYBUNNY   NYBUNN
                      NNYBUNNYBUNNYBUNNY UNN
                     UNN   N Y  N YBUNNYBU
                    BU     NN   N Y    Y
                                NN  UNNY
                                     NNY
                                      NY








READY

Rule 110 Automata on TSS8

 10 DIM A(7)
 20 FOR I=0 TO 7\ READ A(I)\ NEXT I
 30 DATA 0,1,1,1,0,1,1,0
 40 DIM D$(1)\ D$(0)=" "\ D$(1)="#"
 50 DIM D(72)\ D(71)=1 ' DOTS TO PLOT
 60 FOR I=0 TO 71\ PRINT D$(D(I));\ NEXT I\ PRINT
 70 FOR L=1 TO 80
 80  P=0
 90  FOR I=0 TO 71
100   V=A(P*4+D(I)*2+D(I+1))
110   PRINT D$(V);
120   P=D(I)
130   D(I)=V
140  NEXT I
150  PRINT
160 NEXT L
170 END
                                                              #
                                                             ##
                                                            ###
                                                           ## #
                                                          #####
                                                         ##   #
                                                        ###  ##
                                                       ## # ###
                                                      ####### #
                                                     ##     ###
                                                    ###    ## #
                                                   ## #   #####
                                                  #####  ##   #
                                                 ##   # ###  ##
                                                ###  #### # ###
                                               ## # ##  ##### #
                                              ######## ##   ###
                                             ##      ####  ## #
                                            ###     ##  # #####
                                           ## #    ### ####   #
                                          #####   ## ###  #  ##
                                         ##   #  ##### # ## ###
                                        ###  ## ##   ######## #
                                       ## # ######  ##      ###
                                      #######    # ###     ## #
                                     ##     #   #### #    #####
                                    ###    ##  ##  ###   ##   #
                                   ## #   ### ### ## #  ###  ##
                                  #####  ## ### ###### ## # ###
                                 ##   # ##### ###    ######## #
                                ###  ####   ### #   ##      ###
                               ## # ##  #  ## ###  ###     ## #
                              ######## ## ##### # ## #    #####
                             ##      ######   ########   ##   #
                            ###     ##    #  ##      #  ###  ##
                           ## #    ###   ## ###     ## ## # ###
                          #####   ## #  ##### #    ########## #
                         ##   #  ##### ##   ###   ##        ###
                        ###  ## ##   ####  ## #  ###       ## #
                       ## # ######  ##  # ##### ## #      #####
                      #######    # ### ####   ######     ##   #
                     ##     #   #### ###  #  ##    #    ###  ##
                    ###    ##  ##  ### # ## ###   ##   ## # ###
                   ## #   ### ### ## ######## #  ###  ####### #
                  #####  ## ### ######      ### ## # ##     ###
                 ##   # ##### ###    #     ## #########    ## #
                ###  ####   ### #   ##    #####       #   #####
               ## # ##  #  ## ###  ###   ##   #      ##  ##   #
              ######## ## ##### # ## #  ###  ##     ### ###  ##
             ##      ######   ######## ## # ###    ## ### # ###
            ###     ##    #  ##      ######## #   ##### ##### #
           ## #    ###   ## ###     ##      ###  ##   ###   ###
          #####   ## #  ##### #    ###     ## # ###  ## #  ## #
         ##   #  ##### ##   ###   ## #    ####### # ##### #####
        ###  ## ##   ####  ## #  #####   ##     #####   ###   #
       ## # ######  ##  # ##### ##   #  ###    ##   #  ## #  ##
      #######    # ### ####   ####  ## ## #   ###  ## ##### ###
     ##     #   #### ###  #  ##  # ########  ## # #####   ### #
    ###    ##  ##  ### # ## ### ####      # #######   #  ## ###
   ## #   ### ### ## ######## ###  #     ####     #  ## ##### #
  #####  ## ### ######      ### # ##    ##  #    ## #####   ###
 ##   # ##### ###    #     ## ######   ### ##   #####   #  ## #
###  ####   ### #   ##    #####    #  ## ####  ##   #  ## #####